کنترل چراغ چشمک‌زن ESP32 با پنل وب از طریق پروتکل WebSocket

				
					/**
 * @brief WebSocket event handler.
 *
 * @param server Pointer to the WebSocket server instance.
 * @param client Pointer to the WebSocket client.
 * @param type Type of WebSocket event (connect, disconnect, data, etc.).
 * @param arg Additional event-specific data.
 * @param data Data sent by the client (as an array of bytes).
 * @param len  Length of the data array.
 */
void onEvent(AsyncWebSocket *server, AsyncWebSocketClient *client,
             AwsEventType type, void *arg, uint8_t *data, size_t len)
{
  switch (type)
  {
  case WS_EVT_CONNECT:
    Serial.printf("WebSocket client #%u connected from %s\n",
                  client->id(), client->remoteIP().toString().c_str());
    client->text(statusData());
    break;

  case WS_EVT_DISCONNECT:
    Serial.printf("WebSocket client #%u disconnected\n", client->id());
    break;

  case WS_EVT_DATA:
    handleWebSocketMessage(arg, data, len);
    break;

  case WS_EVT_PONG:
  case WS_EVT_ERROR:
    break;
  }
}


/**
 * @brief Handles messages received from the WebSocket client.
 *
 * @param arg  Event-specific argument (castable to AwsFrameInfo).
 * @param data Data sent by the client (as an array of bytes).
 * @param len  Length of the received data.
 */
void handleWebSocketMessage(void *arg, uint8_t *data, size_t len)
{
  AwsFrameInfo *info = (AwsFrameInfo *)arg; // Cast the generic argument to frame info.

  // Ensure this is a complete text frame.
  if (info->final && info->index == 0 && info->len == len && info->opcode == WS_TEXT)
  {
    data[len] = 0;             // Null-terminate the received data.
    String msg = (char *)data; // Convert byte array to String.

    Serial.print("Received Data: ");
    Serial.println(msg);

    if (msg == "BLINK_ON")
    {
      blinkStatus = true;
    }
    else if (msg == "BLINK_OFF")
    {
      blinkStatus = false;
      digitalWrite(LED_PIN, LOW);
    }
    else if (msg.startsWith("DELAY:"))
    {
      blinkDelay = msg.substring(6).toInt(); // Extract delay value from message.
    }
  }
}